如何在使用JAXB schemagen时避免继承？

Question

我正在使用JAXB注解和schemagen这个Maven插件来创建一个xsd文件。我需要用wsdl2py来处理这个xsd，以便生成一个Python客户端。但是因为我的类里有继承关系，schemagen生成的内容看起来像这样：

<xs:complexType name="b">
  <xs:complexContent>
    <xs:extension base="a">
      <xs:sequence>
        <xs:element name="field1" type="xs:string"/>
      </xs:sequence>
    </xs:extension>
  </xs:complexContent>
</xs:complexType>

对于这个类：

class B extends A{
  @XmlElement(required="true")
  private String field1;
}

问题是wsdl2py不理解xs:complexContent和xs:extension这些东西。所以我想生成一个没有继承关系的xsd。

提前谢谢你们！

Answer 1

这是wsdl2py的一个缺点，而不是JAXB的问题，不过这个问题很容易解决，可以用XSLT或XQuery来处理。下面是一个用XSLT快速尝试修复的例子：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsd="http://www.w3.org/2001/XMLSchema">
    <xsl:template match="xsd:complexType[xsd:complexContent/xsd:extension]">

        <xsd:complexType>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates select="xsd:annotation" />

            <xsd:sequence>

                <xsl:variable name="typeQName" select="string(xsd:complexContent/xsd:extension/@base)" />
                <xsl:variable name="typeName"><xsl:choose>
                        <xsl:when test="contains($typeQName, ':')">
                            <xsl:value-of select="substring-after($typeQName, ':')" />
                        </xsl:when>
                        <xsl:otherwise>
                            <xsl:value-of select="$typeQName" />
                        </xsl:otherwise>
                    </xsl:choose></xsl:variable>
                <xsl:comment>Included from <xsl:value-of select="$typeQName" />):
                </xsl:comment>
                <xsl:apply-templates select="//xsd:complexType[@name=$typeName]/*" />
                <xsl:comment>Original extension:</xsl:comment>
                <xsl:apply-templates select="xsd:complexContent/xsd:extension/*" />
            </xsd:sequence>

            <xsl:apply-templates
                select="xsd:attribute | xsd:attributeGroup | xsd:attributeGroup" />
        </xsd:complexType>

    </xsl:template>

    <!-- General copy rule -->
    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*" />
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

有几点需要注意：这个方法只适用于扩展，不适用于限制，并且使用了一个嵌套的序列，wsdl2py可能支持也可能不支持（应该很容易修复）。

目前，它只支持内容模型，但可以很容易扩展来复制属性和属性组。

另外，这个样式表只有在扩展的元素和基础元素在同一个模式文件中时才有效。

祝你好运！